Add automake support for dtl

3rdparty/Makefile.am

@@ -25,7 +25,11 @@ if USE_INCLUDED_ZLIB
 ZLIB = zlib
 endif
 
-SUBDIRS = $(BOOST) $(HUNSPELL) $(MYTHES) $(ICONV) $(ZLIB)
+if BUILD_INCLUDED_DTL
+DTL=dtl
+endif
+
+SUBDIRS = $(BOOST) $(DTL) $(HUNSPELL) $(MYTHES) $(ICONV) $(ZLIB)
 
 EXTRA_DIST = \
 	scripts/evince_sync/evince_backward_search \

3rdparty/dtl/Makefile.am

@@ -0,0 +1,24 @@
+include $(top_srcdir)/config/common.am
+
+man1_MANS = dt2dv.man dv2dt.man
+
+bin_PROGRAMS = dt2dv dv2dt
+
+EXTRA_DIST = \
+	ChangeLog-LyX \
+	CMakeLists.txt \
+	dtl.doc \
+	dvi.doc \
+	edited.txt \
+	example.tex \
+	hello.tex \
+	man2ps \
+	README \
+	tripvdu.tex
+
+HEADERFILES = dtl.h
+
+dt2dv_SOURCES = dt2dv.c $(HEADERFILES)
+
+dv2dt_SOURCES = dv2dt.c $(HEADERFILES)
+

config/lyxinclude.m4

@@ -607,6 +607,21 @@ dnl prevent clash with system zlib that might be dragged in by other libs
 ])
 
 
+dnl Usage: LYX_BUILD_INCLUDED_DTL : select if the included dtl should
+dnl        be built and installed.
+AC_DEFUN([LYX_BUILD_INCLUDED_DTL],[
+	AC_MSG_CHECKING([whether to build dv2dt and dt2dv])
+	AC_ARG_WITH(included-dtl,
+	    [AS_HELP_STRING([--with-included-dtl], [build and install the dv2dt and dt2dv programs supplied with LyX])],
+	    [lyx_cv_with_included_dtl=$withval],
+	    [lyx_cv_with_included_dtl=no])
+	AM_CONDITIONAL(BUILD_INCLUDED_DTL, test x$lyx_cv_with_included_dtl = xyes)
+	AC_MSG_RESULT([$lyx_cv_with_included_dtl])
+	if test x$lyx_cv_with_included_dtl = xyes ; then
+	    lyx_flags="$lyx_flags build-dtl"
+	fi])
+
+
 dnl Usage: LYX_CHECK_CALLSTACK_PRINTING: define LYX_CALLSTACK_PRINTING if the
 dnl        necessary APIs are available to print callstacks.
 AC_DEFUN([LYX_CHECK_CALLSTACK_PRINTING],

configure.ac

@@ -129,6 +129,9 @@ LYX_USE_INCLUDED_ICONV
 ### check for compression support
 LYX_USE_INCLUDED_ZLIB
 
+### check whether we build and install the supplied dtl programs
+LYX_BUILD_INCLUDED_DTL
+
 ### check for file magic support (currently optional)
 AC_CHECK_HEADERS(magic.h,
  [AC_CHECK_LIB(magic, magic_open, [LIBS="$LIBS -lmagic"],
@@ -331,6 +334,7 @@ AC_CONFIG_FILES([Makefile \
       lyx.1:lyx.1in \
       3rdparty/Makefile \
       3rdparty/boost/Makefile \
+      3rdparty/dtl/Makefile \
       3rdparty/hunspell/Makefile \
       3rdparty/mythes/Makefile \
       3rdparty/libiconv/Makefile \