fix bug #7288: add configure option for external mythes library

git-svn-id: svn://svn.lyx.org/lyx/lyx-devel/trunk@37585 a592a061-630c-0410-9148-cb99ea01b6c8

config/lyxinclude.m4

@@ -313,7 +313,7 @@ AM_CONDITIONAL(LYX_BUILD_PCH, test "$lyx_pch_comp" = yes)
 dnl Usage: LYX_USE_INCLUDED_BOOST : select if the included boost should
 dnl        be used.
 AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
-	AC_MSG_CHECKING([whether to use boost included library])
+	AC_MSG_CHECKING([whether to use included boost library])
 	AC_ARG_WITH(included-boost,
 	    [AC_HELP_STRING([--without-included-boost], [do not use the boost lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
 	    [lyx_cv_with_included_boost=$withval],
@@ -337,6 +337,37 @@ AC_DEFUN([LYX_USE_INCLUDED_BOOST],[
 ])
 
 
+dnl Usage: LYX_USE_INCLUDED_MYTHES : select if the included MyThes should
+dnl        be used.
+AC_DEFUN([LYX_USE_INCLUDED_MYTHES],[
+	AC_MSG_CHECKING([whether to use included MyThes library])
+	AC_ARG_WITH(included-mythes,
+	    [AC_HELP_STRING([--without-included-mythes], [do not use the MyThes lib supplied with LyX, try to find one in the system directories - compilation will abort if nothing suitable is found])],
+	    [lyx_cv_with_included_mythes=$withval],
+	    [lyx_cv_with_included_mythes=yes])
+	AM_CONDITIONAL(USE_INCLUDED_MYTHES, test x$lyx_cv_with_included_mythes = xyes)
+	AC_MSG_RESULT([$lyx_cv_with_included_mythes])
+	if test x$lyx_cv_with_included_mythes != xyes ; then
+		AC_LANG_PUSH(C++)
+		AC_CHECK_HEADER(mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes.hxx>"])
+		if test x$ac_cv_header_mythes_h != xyes; then
+			AC_CHECK_HEADER(mythes/mythes.hxx,[ac_cv_header_mythes_h=yes lyx_cv_mythes_h_location="<mythes/mythes.hxx>"])
+		fi
+		AC_CHECK_LIB(mythes, main, [MYTHES_LIBS="-lmythes" lyx_mythes=yes], [lyx_mythes=no], [-lm])
+		if test x$lyx_mythes != xyes; then
+			AC_CHECK_LIB(mythes-1.2, main, [MYTHES_LIBS="-lmythes-1.2" lyx_mythes=yes], [lyx_mythes=no], [-lm])
+		fi
+		AC_LANG_POP(C++)
+		if test x$lyx_mythes != xyes -o x$ac_cv_header_mythes_h != xyes; then
+			LYX_ERROR([No suitable MyThes library found (do not use --without-included-mythes)])
+		fi
+		AC_DEFINE(USE_EXTERNAL_MYTHES, 1, [Define as 1 to use an external MyThes library])
+		AC_DEFINE_UNQUOTED(MYTHES_H_LOCATION,$lyx_cv_mythes_h_location,[Location of mythes.hxx])
+		AC_SUBST(MYTHES_LIBS)
+	fi
+])
+
+
 dnl Usage: LYX_WITH_DIR(dir-name,desc,dir-var-name,default-value,
 dnl                       [default-yes-value])
 dnl  Adds a --with-'dir-name' option (described by 'desc') and puts the

configure.ac

@@ -97,6 +97,7 @@ AC_SUBST(LIBPSAPI)
 AC_CHECK_LIB(gdi32, main)
 
 LYX_USE_INCLUDED_BOOST
+LYX_USE_INCLUDED_MYTHES
 
 # Needed for our char_type
 AC_CHECK_SIZEOF(wchar_t)

src/Makefile.am

@@ -15,7 +15,7 @@ SUBDIRS = support frontends . $(CLIENT) tex2lyx
 
 EXTRA_DIST = pch.h
 
-OTHERLIBS = $(BOOST_LIBS) $(INTLLIBS) $(MYTHES_LIBS) $(AIKSAURUS_LIBS) \
+OTHERLIBS = $(BOOST_LIBS) $(INTLLIBS) $(MYTHES_LIBS) \
 		 $(ENCHANT_LIBS) @LIBS@ $(SOCKET_LIBS) $(LIBSHLWAPI) $(LIBPSAPI)
 
 noinst_LIBRARIES = liblyxcore.a

src/Thesaurus.cpp

@@ -23,7 +23,11 @@
 #include "support/lstrings.h"
 #include "support/os.h"
 
+#ifdef USE_EXTERNAL_MYTHES
+#include MYTHES_H_LOCATION
+#else
 #include "support/mythes/mythes.hxx"
+#endif
 
 #include "frontends/alert.h"
 

src/support/Makefile.am

@@ -102,10 +102,13 @@ liblyxsupport_a_SOURCES = \
 	userinfo.h \
 	unicode.cpp \
 	unicode.h \
-	weighted_btree.h \
+	weighted_btree.h
+if USE_INCLUDED_MYTHES
+liblyxsupport_a_SOURCES += \
 	mythes/mythes.cxx \
 	mythes/mythes.hxx \
 	mythes/license.readme
+endif
 
 #if INSTALL_MACOSX
 #liblyxsupport_a_SOURCES += \